home *** CD-ROM | disk | FTP | other *** search
/ PC-Blue - MS DOS Public Domain Library / PC-Blue MS-DOS Public Domain Library - NYACC.iso / vol136 / checkbnk.bas < prev    next >
Encoding:
BASIC Source File  |  1986-12-15  |  3.0 KB  |  70 lines
  1. 4000 COLOR 7,0: REM  ***************************************************************************************************
  2. 4010 REM                      'CHECKBNK' SUBROUTINE TO PRINT/ADJUST BANK STATEMENT RECORD
  3. 4020 REM  **************************************************************************************************************
  4. 4030 GOSUB 270   'OPEN PAYEE FILES
  5. 4040 GET #1,1  'GET THE BANK STATEMENT DISKETTE RECORD
  6. 4050 COLOR 7,0: CLS
  7. 4060 PRINT "  BANK STATEMENT AS OF ";DATE$
  8. 4070 PRINT
  9. 4080 PRINT "    ";A1$
  10. 4090 PRINT "    ";A2$
  11. 4100 PRINT "    ";A3$;" ";A4$
  12. 4110 PRINT
  13. 4120 AMT = CVS(S1$)
  14. 4130 PRINT "   1  Starting Bank Balance ";
  15. 4140 PRINT USING "######,.##-";AMT
  16. 4150 AMT = CVS(S2$)
  17. 4160 PRINT "   2  YTD Deposits/Interest ";
  18. 4170 PRINT USING "######,.##-";AMT
  19. 4180 PRINT "         and Withdrawals"
  20. 4190 AMT = CVS(S3$)
  21. 4200 PRINT "   3  YTD Checks Issued     ";
  22. 4210 PRINT USING "######,.##-";AMT
  23. 4220 AMT = CVS(S4$)
  24. 4230 PRINT "   4  Current Bank Balance  ";
  25. 4240 PRINT USING "######,.##-";AMT
  26. 4250 KINT% = CVI(S5$)
  27. 4260 PRINT "   5  Next File #2 Chain Record ";
  28. 4270 PRINT USING "####";KINT%
  29. 4280 KINT% = CVI(S6$)
  30. 4290 PRINT "   6  YTD No. Of Checks Issued  ";
  31. 4300 PRINT USING "####";KINT%
  32. 4310 PRINT "   9  Return to Job Choices Menu"
  33. 4320 PRINT: COLOR 0,7: PRINT "  To change any field above"
  34. 4330 PRINT "  enter CODE and NEW Amount": BEEP: BEEP: COLOR 7,0
  35. 4340 PRINT: COLOR 0,7: PRINT "  Code = ";: Y = CSRLIN: X = POS(0)
  36. 4350 FIELDMAX% = 1: NUM.ONLY% = TRUE%: DEC.MINUS% = FALSE%: GOSUB 330
  37. 4360 IF DATU$="9" THEN GOTO 4640
  38. 4370 B$ = DATU$
  39. 4380 LOCATE Y,X+5: PRINT "  New Amount = ";: Y = CSRLIN: X = POS(0)
  40. 4390 FIELDMAX% = 9: NUM.ONLY% = TRUE%: DEC.MINUS% = TRUE%: GOSUB 330
  41. 4400 AMT = VAL(DATU$)
  42. 4410 LOCATE Y,X+1: COLOR 0,7: IF B$ < "5" THEN PRINT USING "#####,.##";AMT: ELSE PRINT USING "    #####";AMT
  43. 4420 COLOR 7,0
  44. 4430 IF B$ = "1" THEN GOTO 4500
  45. 4440 IF B$ = "2" THEN GOTO 4510
  46. 4450 IF B$ = "3" THEN GOTO 4520
  47. 4460 IF B$ = "4" THEN GOTO 4530
  48. 4470 IF B$ = "5" THEN GOTO 4540
  49. 4480 IF B$ = "6" THEN GOTO 4560
  50. 4490 COLOR 31,0: PRINT "  Invalid CODE was entered, retry": COLOR 7,0: GOTO 4340
  51. 4500 LSET S1$ = MKS$(AMT): GOTO 4580
  52. 4510 LSET S2$ = MKS$(AMT): GOTO 4580
  53. 4520 LSET S3$ = MKS$(AMT): GOTO 4580
  54. 4530 LSET S4$ = MKS$(AMT): GOTO 4580
  55. 4540 KINT% = AMT
  56. 4550 LSET S5$ = MKI$(KINT%): GOTO 4580
  57. 4560 KINT% = AMT
  58. 4570 LSET S6$ = MKI$(KINT%): GOTO 4580
  59. 4580 PRINT: PRINT: COLOR 0,7: PRINT "  Want to change another field?"
  60. 4590 PRINT "  Reply Y or N ";
  61. 4600 B$=INKEY$: IF B$="" THEN 4600
  62. 4610 PRINT B$: IF B$="Y" OR B$="y" THEN GOTO 4050
  63. 4620 IF B$="N" OR B$="n" THEN GOTO 4640
  64. 4630 PRINT: COLOR 31,0: PRINT "  I need a Y or N, try again ";: COLOR 7,0: GOTO 4600
  65. 4640 PUT #1,1
  66. 4650 CLOSE #1,#2
  67. 4660 GOTO 260  'RETURN TO UTILITY JOB CHOICES MENU
  68. 4670 REM  --------------------------------------------------------------------------------------------------------------
  69. 9000 GOTO 9000  'CHAIN MERGE AREA LAST STATEMENT
  70. -------------------------------------------------------------